™유진's Blog

거의 기본적인 기능으로 구현된 업로드 매너저를 만들어 보았다.
파일을 선택했을때 파일명과 파일이 저장된 저장경로를 사용자 이벤트를 통하여 디스패치 시켰다.




UploadMgr.as

1. package managers
2. {
3.     import events.UploadEvent;
4.    
5.     import flash.events.DataEvent;
6.     import flash.events.Event;
7.     import flash.events.EventDispatcher;
8.     import flash.events.IOErrorEvent;
9.     import flash.events.SecurityErrorEvent;
10.     import flash.net.FileFilter;
11.     import flash.net.FileReference;
12.     import flash.net.URLRequest;
13.    
14.     import mx.controls.Alert;
15.    
16.     public class UploadMgr extends EventDispatcher
17.     {
18.         private var _fileRef:FileReference;
19.         private var _fileSavePath:String;
20.        
21.         public function get fileSavePath():String
22.         {
23.             return _fileSavePath
24.         }
25.        
26.         public function UploadMgr()
27.         {
28.             _fileRef = new FileReference();
29.             _fileRef.addEventListener(Event.SELECT, fileSelectHandler);
30.             _fileRef.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA, fileUploadCompleteDataHandler);
31.             _fileRef.addEventListener(IOErrorEvent.IO_ERROR, fileIOErrorHandler);
32.             _fileRef.addEventListener(SecurityErrorEvent.SECURITY_ERROR, fileSecuErrorHandler);
33.         }
34.        
35.         public function onFileBrowser():void
36.         {
37.             _fileRef.browse(setFileFilter());
38.         }
39.        
40.         private function setFileFilter():Array
41.         {
42.             var filter0:FileFilter =
43.                 new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
44.            
45.             var filterSet:Array = new Array();
46.             filterSet.push(filter0);
47.            
48.             return filterSet;
49.         }
50.        
51.         public function sendFileRef(url:String):void
52.         {
53.             var request:URLRequest = new URLRequest();
54.             request.url = url;
55.  
56.             _fileRef.upload(request);
57.         }
58.        
59.         private function fileSelectHandler(event:Event):void
60.         {
61.             var name:String = event.currentTarget.name;
62.             var e:UploadEvent = new UploadEvent(name, UploadEvent.SELECT);
63.            
64.             dispatchEvent(e);
65.         }
66.        
67.         private function fileUploadCompleteDataHandler(event:DataEvent):void
68.         {
69.             var fileSavePath:String = event.data.toString();
70.             var e:UploadEvent = new UploadEvent(fileSavePath, UploadEvent.COMPLETE_DATA);
71.            
72.             dispatchEvent(e);
73.         }
74.        
75.         private function fileIOErrorHandler(event:IOErrorEvent):void
76.         {
77.             Alert.show("IO Error");
78.         }
79.        
80.         private function fileSecuErrorHandler(event:SecurityErrorEvent):void
81.         {
82.             Alert.show("Security Error");
83.         }
84.     }
85. }

파일필터를 추가할땐 fileSet배열에 추가시켜주면 된다.




UploadEvent.as

1. package events
2. {
3.     import flash.events.Event;
4.  
5.     public class UploadEvent extends Event
6.     {
7.         public static const SELECT:String = "select";
8.         public static const COMPLETE_DATA:String = "completeData"
9.        
10.         public var result:Object;
11.        
12.         public function UploadEvent(result:Object, type:String, bubbles:Boolean=false)
13.         {
14.             super(type, bubbles);
15.             this.result = result;
16.         }
17.        
18.         override public function clone():Event
19.         {
20.             return new UploadEvent(result, type, bubbles);
21.         }
22.     }
23. }

적용 액션스크립트 코드

1. import events.UploadEvent;
2. import managers.UploadMgr;
3.  
4. private var uploadMgr:UploadMgr;
5.  
6. private function init():vod
7. {
8.     uploadMgr = new UploadMgr();
9.     uploadMgr.addEventListener(UploadEvent.SELECT, fileSelectHandler);
10.     uploadMgr.addEventListener(UploadEvent.COMPLETE_DATA, fileUploadCompleteDataHandler);
11. }
12.  
13. private function fileSelectHandler(event:UploadEvent):void
14. {
15.     var fileName:String = event.result.toString();
16. }
17.  
18. private function fileUploadCompleteDataHandler(event:UploadEvent):void
19. {
20.     var fileSavePath:String = event.result.toString();
21. }